<!-- #include file="gtmlang.inc" -->
<!-- #include file="gtmconfig.inc" -->
<!-- #include file="../../../include/browsercap.asp" -->
<%
sHEImagePath = "common/htmleditor2/"
%>
<!-- #include file="../htmleditor2/htmleditor.asp" -->
<%

' Generic Table Manager (GTM) : gtm.asp
'
' The GTM is a powerful tool that dramatically reduces the time spent in building CREATE,
' UPDATE, DELETE and RETRIEVE screens for database catalogues. Programmers usually don't
' need to work with this file. They need to edit the tabledef.inc file and GTM will do the
' rest.
'
' I will post a Programmer's Reference document of this tool later.
'
' HISTORY AND BUG REVISION
' ------------------------
'
' I added support of images to GTM.
'
' 1.1.5 (11/12/2002)
' Carlos A. Madrigal
' 
' I added the F_UNIQUE flag to control fields with unique values. This enhancement was needed
' to correct an IMM bug.
'
' If you are using this version of GTM with IMM, please add the following line to your IMM
' tabledef.inc file:
'
' ****** SetFieldFlag "mmSubscribers", "Email", F_UNIQUE, True
'
' 1.1.4	(11/06/2002)
' Carlos A. Madrigal
' 
' I fixed a bug on the ONE TO MANY control. That caused that some values were marked by
' default even though there weren't records on the table. I also enhaced the error mechanism.
'
' 1.1.3	(11/06/2002)
' Carlos A. Madrigal
'
' I made modifications to GTM to be able to integrate to SBIIA 1.1.
'
' 1.1.2	(07/20/2002)
' Carlos A. Madrigal
'
' NO HISTORY AVAILABLE
'
' 1.1.1	(05/15/2002)
' Carlos A. Madrigal
'
' NO HISTORY AVAILABLE
'
' 1.1.0	(04/24/2002)
' Julio César Martínez
'
' NO HISTORY AVAILABLE
'
' 1.0.0	(11/27/2001)
' Carlos A. Madrigal
' 
' Copyright © 1999-2003 Infolink Aplicaciones, S.A. de C.V.  
' All rights reserved
' Derechos de Autor © 1999-2003 Infolink Aplicaciones, S.A. de C.V.
' Derechos Reservados.
'
'**Start Encode**
' Constants
Const F_FIELD_NAME = "FieldName"
Const F_VALUE = "Value"
Const F_DESC = "Description"
Const F_ISKEY = "IsKey?"
Const F_USEQUOTES = "UseQuotes?"
Const F_INLIST = "InList?"
Const F_UPDATABLE = "CanBeUpdated?"
Const F_HIDDEN = "IsHidden?"
Const F_SEARCHABLE = "IsSearchable?"
Const F_NULLABLE = "Nullable"
Const F_TYPE = "Type"
Const F_TEXT = "Text"
Const F_MEMO = "Memo"
Const F_NUMBER = "Number"
Const F_SELECT = "Select"
Const F_VALUESELECT = "ComboFromValue"
Const F_VALUEOPTIONS = "OptionsFromValue"
Const F_VALUEEMPTY = "SelectNullOrEmpty"
Const F_INT = "Integer"
Const F_EMAIL = "EMail"
Const F_SIZEW = "SizeW"
Const F_SIZEH = "SizeH"
Const F_SOURCE = "Source"
Const F_NEWMSG = "NewMsg"
Const F_EDITMSG = "EditMsg"
Const F_FILE = "File"
Const F_DATE_MMDDYYYY  = "Date"
Const F_US_PHONE = "USPhone"
Const F_BOOL = "Bool"		
Const F_FILEPATH = "FilePath" 
Const F_DATAFORMAT = "DataFormat"
Const F_TIME_HHMM = "Time"
Const F_AUTOGEN = "AutoGenerated"
Const F_HTML_FORMAT ="HTMLFormat"
Const F_HINTTEXT = "HintText"
Const F_TABLELISTTEXT = "TableListText"
Const F_RECORDLISTTEXT = "RecordListText"
Const F_RECORDEDITTEXT = "RecordEditText"
Const F_RECORDLISTORDER = "RecordListOrder"
Const F_FILTERBYLANG = "FilterByLang"
Const F_ACTIONSALLOWED = "ActionsAllowed"
Const F_SECADD = "A"
Const F_SECDEL = "D"
Const F_SECEDIT = "E"
Const F_SECRETR = "R"
Const F_SECPICK = "P"
Const F_SECALL = "ADERP"
Const F_ONETOMANY = "OneToManyRelationship"
Const F_MANYVALUES = "ManyValues" 
Const F_FIELDLEN = "FieldLength"
Const F_UNIQUE = "IsThisValueUnique"
Const IMAGE_FOLDER = "../images/"
Const IMAGE_FOLDER_TRANSFORMED = "images/"

' User-defined variables
Dim sGTMMailTo, sGTMSolution, sGTMFontFace, sGTMFontSize, sGTMFieldBG, sGTMSizeW, sGTMSizeH 
Dim lGTMRecsPerPage
Dim sCmd, sPage, sBTUFieldBG 
Dim dicTables, dicField, sTable, cmdIsSafeToDelete, sQuery, rsStoringDate
Dim sProgrammer, sSolution, sData, bIsImage, sFileLookup, sFieldLookup, sFilePath, bShowSearchForm, sDataFormat
Dim sTableName, sFieldName, sFields, dicKeyFields, dicWorkFields, lPage, bBOF, bEOF, lRecIndex, iHTMLCounter
Dim bEnableErrors
%>
<!-- #include file="gtmconfig.inc" -->
<!-- #include file="gtmcommon.inc" -->
<!-- #include file="commondb.inc" -->
<%


Sub RaiseGTMError(sFunction, sError)
	If Err.Number <> 0 Then
		%>
		<div>
		<font size=2 color=red>
			<p><b>A GTM error has occured</b></p>
			<p>The following function failed: <b><font color=#666666><%=sFunction%></font></b>.</p>
			<p>The reported error is: <font color=#666666></p>
			<blockquote><%=sError%></blockquote>
			</font></p>
		</font>
		</div>
		<%
		SendError Err.Number, Err.Description, sError, ""
		Response.End
	End If
	Err.Clear
End Sub

Sub AddTable(sTableName, sTableDesc)
	Dim dicTable, dicFields
	Set dicTable = Server.CreateObject("Scripting.Dictionary")
	Set dicFields = Server.CreateObject("Scripting.Dictionary")
	If Len(Trim(sTableDesc))=0 Then sTableDesc = sTableName
	dicTables.Add sTableName, dicTable
	dicTable.Add "Fields", dicFields
	dicTable.Add F_DESC, sTableDesc
	dicTable.Add F_ACTIONSALLOWED, F_SECALL
End Sub

Sub AddField(sTableName, sFieldName, sFieldDesc, bUseQuotes, bIncludeInList)
	Dim dicField
	Set dicField = Server.CreateObject("Scripting.Dictionary")
	If Len(sFieldDesc) > 0 Then
		dicField.Add GTM_DESCRIPTION_CAPTION, sFieldDesc
	Else
		dicField.Add GTM_DESCRIPTION_CAPTION, sFieldName
	End If
	dicField.Add F_FIELD_NAME, sFieldName
	dicField.Add F_VALUE, vbNullString
	dicField.Add F_ISKEY, False
	dicField.Add F_UNIQUE, False
	dicField.Add F_NULLABLE, True
	dicField.Add F_SEARCHABLE, False
	dicField.Add F_USEQUOTES, bUseQuotes
	dicField.Add F_INLIST, bIncludeInList
	dicField.Add F_VALUEEMPTY, vbNullString
	dicField.Add F_UPDATABLE, True
	dicField.Add F_HIDDEN, False
	dicField.Add F_TYPE, F_TEXT
	dicField.Add F_SIZEW, sGTMSizeW
	dicField.Add F_SIZEH, sGTMSizeH
	dicField.Add F_DATAFORMAT, sDataFormat
	dicField.Add F_HINTTEXT, vbNullString	
	dicField.Add F_TABLELISTTEXT, vbNullString	
	dicField.Add F_RECORDLISTTEXT, vbNullString	
	dicField.Add F_RECORDEDITTEXT, vbNullString
	dicField.Add F_FIELDLENGTH, vbNullString
	dicTables(sTableName)("Fields").Add sFieldName, dicField
End Sub

Sub SetTableFlag(sTableName, sFlagName, bFlag)
	Dim dicTable
	Set dicTable = dicTables(sTableName)
	If dicTable.Exists(sFlagName) Then
		dicTable(sFlagName) = bFlag
	Else
		dicTable.Add CStr(sFlagName), bFlag
	End If
End Sub

Sub SetFieldFlag(sTableName, sFieldName, sFlagName, bFlag)
	Dim dicField
	On Error Resume Next
	Set dicField = dicTables(sTableName)("Fields")(sFieldName)
	RaiseGTMError "SetFieldFlag", "You didn't add this field first: " & sTableName & "." & sFieldName
	If dicField.Exists(CStr(sFlagName)) Then
		dicField(CStr(sFlagName)) = bFlag
		RaiseGTMError "SetFieldFlag", "Cannot set value to flag: " & sTableName & "." & sFieldName & "!" & sFlagName  & " = " & bFlag
	Else
		dicField.Add CStr(sFlagName), bFlag
		RaiseGTMError "SetFieldFlag", "Cannot set value to flag: " & sTableName & "." & sFieldName & "!" & sFlagName  & " = " & bFlag
	End If
	If sFlagName = F_TYPE Then '
		Select Case bFlag
			Case F_NUMBER, F_INT
				SetFieldFlag sTableName, sFieldName, F_SIZEW, 8
			Case F_DATE_MMDDYYYY
				SetFieldFlag sTableName, sFieldName, F_SIZEW, 12
				SetFieldFlag sTableName, sFieldName, F_HINTTEXT, "(mm/dd/yyyy)"
		End Select
	ElseIf sFlagName = F_FILEPATH Then
		If Len( bFlag )= 0 Then
			dicField(F_FILEPATH) = "./"
		End If
	End If
	If VarType(bFlag) = vbBoolean Then 
		If sFlagName = F_ISKEY And bFlag Then
			SetFieldFlag sTableName, sFieldName, F_UPDATABLE, False
			SetFieldFlag sTableName, sFieldName, F_NULLABLE, False
		End If
	End If
End Sub

Sub PaintField(sFieldName, dicField)
	Dim sFldType, sOneToManySQL, rsOneToMany, sComboSQL, rsComboSQL, sSelected, sCheckedTrue, sCheckedFalse 
	Dim sRow, asRows, asCols
	Dim obFSO, obFiles, obFile
	Dim asSource, sSourceSQL, rsSource, sChecked
	Dim iCount
	
	sFldType = dicField(F_TYPE)
	
	If sFldType = F_HTML_FORMAT Then
		sImageSource = dicField(F_SOURCE)
		iControlHt = dicField(F_SIZEH)
		If iControlHt = 0 Or iControlHt = "" Or iControlHt < 100 Then iControlHt = 300
		
		'If Len(sImageSource) = 0 Then
		%>
		<INPUT TYPE="HIDDEN" NAME="<%=sFieldName%>" VALUE="<%=Server.HTMLEncode(dicField(F_VALUE))%>">
		<TABLE WIDTH="100%">
			<tr valign=top HEIGHT="100%">
				<TD>
					
					<% If bolDisplayNewEditor Then %>
					<script>
					var htmlContent<%=iHTMLCounter%> = new InnovaEditor("htmlContent<%=iHTMLCounter%>");
					htmlContent<%=iHTMLCounter%>.scriptPath="common/htmleditor/scripts/";
					htmlContent<%=iHTMLCounter%>.width="100%";
					htmlContent<%=iHTMLCounter%>.CharSet="big5"
					htmlContent<%=iHTMLCounter%>.btnAssets=true;	
					htmlContent<%=iHTMLCounter%>.btnAssetManager=true;
					htmlContent<%=iHTMLCounter%>.cmdAssetManager="modalDialogShow('common/htmleditor/assetmanager/assetmanager.asp',680,520)";	
					htmlContent<%=iHTMLCounter%>.RENDER();		
					htmlContent<%=iHTMLCounter%>.loadHTML("<%=HtmlToJSString(Replace(dicField(F_VALUE), IMAGE_FOLDER_TRANSFORMED, IMAGE_FOLDER))%>");
					</script>
					<%Else
					HTMLEdit sFieldName, "htmlContent" & iHTMLCounter, iControlHt
					End If%> 
				</TD>
		</TR>
		</TABLE>
		<%
		'Else
			' Restore image paths
		'	Set re = New RegExp
		'	re.Global = True
		'	re.Pattern = dicField(F_SOURCE) + "/"
		'	sFieldValue = re.Replace(dicField(F_VALUE), "../" + dicField(F_SOURCE) + "/")
		%>
		<%
		'End If
		
		Exit Sub
	End If
	If sFldType = F_ONETOMANY Then
		If sCmd = "E" Then
			asSource = Split(dicField(F_SOURCE), ";")
			sSourceSQL = "SELECT " + asSource(2) + " FROM " + asSource(0) + " WHERE " + KeyCriteria
			Set rsSource = conDB.Execute(sSourceSQL)
			dicField(F_VALUE) = " "
			While Not rsSource.EOF
				dicField(F_VALUE) = dicField(F_VALUE) & rsSource(0) & " "
				rsSource.MoveNext
			Wend
			rsSource.Close
		End If
	
		sOneToManySQL = dicField(F_MANYVALUES)
		Set rsOneToMany = conDB.Execute(sOneToManySQL)
		Response.Write "<table width=100% >"
		iCount = 0
		With rsOneToMany
			While Not .EOF
				If iCount Mod 2 = 0 Then Response.Write "<tr>"
				Response.Write "<td width=50% >"
				If InStr(1, dicField(F_VALUE), " " & CStr(.Fields(0).Value) & " ") > 0 Then	sChecked = " checked" Else sChecked = ""
				Response.Write "<input type=checkbox name='" & sFieldName & "' value='" & .Fields(0) & "'" & sChecked & "> " & AddFontTag(.Fields(1)) & "<br>"
				.MoveNext
				Response.Write "</td>"
				If iCount Mod 2 = 1 Then Response.Write "</tr>"
				iCount = iCount + 1
			Wend
		End With
		Response.Write "</table>"
		Exit Sub
	End If
	If sFldType = F_MEMO Then
		Response.Write "<TEXTAREA CLASS=""gtmControl"" NAME=""" & sFieldName & """ COLS=""" & (CLng(dicField(F_SIZEW))-5) & _
			""" ROWS=""" & dicField(F_SIZEH) & """>" & dicField(F_VALUE) & "</TEXTAREA>"
		Exit Sub
	End If
	If sFldType = F_SELECT Then
		sComboSQL = dicField(F_SOURCE)
		If Len(sComboSQL) > 0 Then
			Set rsComboSQL = conDB.Execute(sComboSQL)
			Response.Write vbCrLf + "<!-- SQL: " & sComboSQL & " -->" + vbCrLf
			Response.Write "<SELECT CLASS=""gtmControl"" NAME=""" & sFieldName & """>" + vbCrLf
			If dicField(F_NULLABLE) Then													
				If Len(dicField(F_VALUE)) = 0 Then											
					sSelected = " SELECTED"													
				Else																		
					sSelected = vbNullString												
				End If																		
				If Len(dicField(F_VALUEEMPTY)) > 0 Then
					Response.Write "<OPTION VALUE=""" _
						& Split(dicField(F_VALUEEMPTY), ";")(0) _
						& """ " + sSelected + ">" _
						& Split(dicField(F_VALUEEMPTY), ";")(1) _
						& "</OPTION>" + vbCrLf 'CAMP
				Else																		
					Response.Write "<OPTION VALUE="""" " + sSelected + "></OPTION>" + vbCrLf
				End If																		
			End If																			
			With rsComboSQL
				While Not .EOF
					If CStr(dicField(F_VALUE)) = CStr(.Fields(0)) Then
						sSelected = " SELECTED"
					Else
						sSelected = vbNullString
					End If
					Response.Write "<OPTION VALUE=""" & .Fields(0) & """" + sSelected + ">" & _
						.Fields(1) & "</OPTION>" + vbCrLf
					.MoveNext
				Wend 
			End With
			Response.Write "</SELECT>" + vbCrLf
			Exit Sub
		End If		
	End If
	If sFldType = F_VALUESELECT Then
		asRows = Split(dicField(F_SOURCE), ";")
		Response.Write "<SELECT CLASS=""gtmControl"" NAME=""" & sFieldName & """>"
		If Len(dicField(F_VALUEEMPTY)) > 0 Then 
			asCols = Split(dicField(F_VALUEEMPTY), ";")
		Else
			asCols = Split(";N/A", ";")
		End If
		If dicField(F_NULLABLE) Then													
			If CStr(dicField(F_VALUE)) = asCols(0) Then									
				sSelected = " SELECTED"													
			Else																		
				sSelected = vbNullString												
			End If																		
			Response.Write "<OPTION VALUE=""" _
				& asCols(0) _
				& """ " + sSelected + ">" _
				& asCols(1) _
				& "</OPTION>" + vbCrLf 
		End If																			
		For Each sRow In asRows
			asCols = Split(sRow, ":")
			If asCols(0) = CStr(dicField(F_VALUE)) Then
				sSelected = " SELECTED"
			Else
				sSelected = vbNullString
			End If
			Response.Write "<OPTION VALUE=""" & asCols(0) & """" + sSelected + ">" & _
				asCols(1) & "</OPTION>" + vbCrLf
		Next
		Response.Write "</SELECT>"
		Exit Sub
	End If
	If sFldType = F_VALUEOPTIONS Then
		asRows = Split(dicField(F_SOURCE), ";")
		If Len(dicField(F_VALUEEMPTY)) > 0 Then 
			asCols = Split(dicField(F_VALUEEMPTY), ";")
		Else
			asCols = Split(";N/A", ";")
		End If
		If dicField(F_NULLABLE) Then													
			If CStr(dicField(F_VALUE)) = asCols(0) Then									
				sSelected = " CHECKED"													
			Else																		
				sSelected = vbNullString												
			End If																		
			Response.Write _
				"<INPUT TYPE=""RADIO"" CLASS=""gtmControl"" NAME=""" & sFieldName _
				& """ VALUE=""" & asCols(0) & """" + sSelected + ">" _
				& AddFontTag(asCols(1)) & "<BR>" + vbCrLf
		End If																			
		For Each sRow In asRows
			asCols = Split(sRow, ":")
			If asCols(0) = CStr(dicField(F_VALUE)) Then
				sSelected = " CHECKED"
			Else
				sSelected = vbNullString
			End If
			Response.Write "<INPUT TYPE=""RADIO"" CLASS=""gtmControl"" NAME=""" & sFieldName & """ VALUE=""" & asCols(0) & """" + sSelected + ">" & _
				AddFontTag(asCols(1)) & "<BR>" + vbCrLf
		Next
		Exit Sub
	End If
	If sFldType = F_BOOL Then
		If CStr( dicField(F_VALUE) ) = "True"  Then
			sCheckedTrue  = " CHECKED"
			sCheckedFalse = vbNullString
		Else
			sCheckedTrue  = vbNullString
			sCheckedFalse = " CHECKED"
		End If
		Response.Write "<INPUT TYPE=""Radio"" CLASS=""gtmControl"" NAME=""" + sFieldName + """ VALUE=1" + sCheckedTrue + "> " & AddFontTag("Yes") & vbCrlf _
			& "<INPUT TYPE=""Radio"" CLASS=""gtmControl"" NAME=""" + sFieldName + """ VALUE=0" + sCheckedFalse + "> " & AddFontTag("No")
		Exit Sub	
	End If
	If  sFldType = F_DATE_MMDDYYYY Then
		dicField(F_VALUE) = GetCorrectDate( dicField(F_VALUE) )
		Response.Write "<INPUT CLASS=""gtmControl"" TYPE=""text"" SIZE=""" & dicField(F_SIZEW) & """ NAME=""" + sFieldName + """ VALUE=""" & _
		dicField(F_VALUE) & """>"
		Exit Sub
	End If
	If  sFldType = F_TIME_HHMM Then
		Response.Write "<INPUT CLASS=""gtmControl"" TYPE=""text"" SIZE=""" & dicField(F_SIZEW) & """ NAME=""" + sFieldName + """ VALUE=""" & _
		FormatDateTime(dicField(F_VALUE),4) & IIf(CDate(dicField(F_VALUE))>CDate("12:00")," pm"," am") & """>"
		Exit Sub
	End If
	If sFldType = F_FILE Then
		Set obFSO = Server.CreateObject ( "Scripting.FileSystemObject" )
		If Not obFSO.FolderExists( Server.MapPath ( dicField(F_FILEPATH) ) ) Then
			If Not bEnableErrors Then On Error Resume Next
			If Not obFSO.CreateFolder ( Server.MapPath( dicField(F_FILEPATH) ) ) Then
				SendError Err.number, GTM_FOLDER_ERROR , "The Folder '" & dicField(F_FILEPATH) & "'" & GTM_FOLDER_DESCRIPTION, ""
				Response.End 
			End If
			On Error GoTo 0
		Else
			Set obFiles = obFSO.GetFolder ( Server.MapPath ( dicField(F_FILEPATH) ) ).Files 
			Response.Write "<INPUT CLASS=""gtmControl"" NAME=""" + sFieldName + """ VALUE=""" & dicField(F_VALUE) & """>" & vbCrlf _
				& "<INPUT CLASS=""gtmControl"" TYPE=""button"""  & _
					" onClick=""javascript:ViewFile( document.frmGTM." & sFieldName & ".value, document.frmGTM." & sFieldName & ".value" + ", '" & dicField(F_FILEPATH) & "'" & ");"" " &_
					" VALUE=""" & GTM_PREVIEW_CAPTION & """>&nbsp;&nbsp;" & vbCrlf _
				& "<INPUT CLASS=""gtmControl"" TYPE=""button"" onClick=""javascript:SelectFile('" & sFieldName & "', '" & dicField(F_FILEPATH) & "'" & ");"" VALUE=""" & GTM_SELECT_FILE_CAPTION & """ id=1 name=1> " _
				& "<INPUT CLASS=""gtmControl"" TYPE=""button"" onClick=""javascript:UploadFile('" & sFieldName & "', '" & dicField(F_FILEPATH) & "'" & ");"" VALUE=""" & GTM_UPLOAD_CAPTION & """ id=1 name=1> " 
			Exit Sub
		End If	
	End If			
	
	If Len(dicField(F_FIELDLENGTH)) > 0 Then
		iFieldLength = dicField(F_FIELDLENGTH)
	Else
		iFieldLength = dicField(F_SIZEW)
	End If
	 
	Response.Write "<INPUT CLASS=""gtmControl"" TYPE=""text"" MAXLENGTH=""" & iFieldLength & """ SIZE=""" & dicField(F_SIZEW) & """ NAME=""" + sFieldName + """ VALUE=""" & _
		dicField(F_VALUE) & """>"
End Sub

Sub PaintViewField(sFieldName, dicField)
	Dim sFldType, sComboSQL, rsComboSQL, sSelected, sCheckedTrue, sCheckedFalse 
	Dim sRow, asRows, asCols
	Dim obFSO, obFiles, obFile
	
	sFldType = dicField(F_TYPE)
	
	If sFldType = F_HTML_FORMAT Then
		%>
		<INPUT TYPE="HIDDEN" NAME="<%=sFieldName%>" VALUE="<%=Server.HTMLEncode(dicField(F_VALUE))%>">
		<TABLE WIDTH="100%">
			<tr valign=top HEIGHT="100%">
				<TD><%HTMLEdit sFieldName, "htmlContent" & iHTMLCounter, 300%></TD>
			</TR>
		</TABLE>
		<%
		Exit Sub
	End If
	If sFldType = F_SELECT Then
		sComboSQL = dicField(F_SOURCE)
		If Len(sComboSQL) > 0 Then
			Set rsComboSQL = conDB.Execute(sComboSQL)
			Response.Write vbCrLf + "<!-- SQL: " & sComboSQL & " -->" + vbCrLf
			Response.Write "<SELECT CLASS=""gtmControl"" NAME=""" & sFieldName & """>" + vbCrLf
			If dicField(F_NULLABLE) Then													
				If Len(dicField(F_VALUE)) = 0 Then											
					sSelected = " SELECTED"													
				Else																		
					sSelected = vbNullString												
				End If																		
				If Len(dicField(F_VALUEEMPTY)) > 0 Then
					Response.Write "<OPTION VALUE=""" _
						& Split(dicField(F_VALUEEMPTY), ";")(0) _
						& """ " + sSelected + ">" _
						& Split(dicField(F_VALUEEMPTY), ";")(1) _
						& "</OPTION>" + vbCrLf 'CAMP
				Else																		
					Response.Write "<OPTION VALUE="""" " + sSelected + "></OPTION>" + vbCrLf
				End If																		
			End If																			
			With rsComboSQL
				While Not .EOF
					If CStr(dicField(F_VALUE)) = CStr(.Fields(0)) Then
						sSelected = " SELECTED"
					Else
						sSelected = vbNullString
					End If
					Response.Write "<OPTION VALUE=""" & .Fields(0) & """" + sSelected + ">" & _
						.Fields(1) & "</OPTION>" + vbCrLf
					.MoveNext
				Wend 
			End With
			Response.Write "</SELECT>" + vbCrLf
			Exit Sub
		End If		
	End If
	If sFldType = F_VALUESELECT Then
		asRows = Split(dicField(F_SOURCE), ";")
		Response.Write "<SELECT CLASS=""gtmControl"" NAME=""" & sFieldName & """>"
		If Len(dicField(F_VALUEEMPTY)) > 0 Then 
			asCols = Split(dicField(F_VALUEEMPTY), ";")
		Else
			asCols = Split(";N/A", ";")
		End If
		If dicField(F_NULLABLE) Then													
			If CStr(dicField(F_VALUE)) = asCols(0) Then									
				sSelected = " SELECTED"													
			Else																		
				sSelected = vbNullString												
			End If																		
			Response.Write "<OPTION VALUE=""" _
				& asCols(0) _
				& """ " + sSelected + ">" _
				& asCols(1) _
				& "</OPTION>" + vbCrLf 
		End If																			
		For Each sRow In asRows
			asCols = Split(sRow, ":")
			If asCols(0) = CStr(dicField(F_VALUE)) Then
				sSelected = " SELECTED"
			Else
				sSelected = vbNullString
			End If
			Response.Write "<OPTION VALUE=""" & asCols(0) & """" + sSelected + ">" & _
				asCols(1) & "</OPTION>" + vbCrLf
		Next
		Response.Write "</SELECT>"
		Exit Sub
	End If
	If sFldType = F_VALUEOPTIONS Then
		asRows = Split(dicField(F_SOURCE), ";")
		If Len(dicField(F_VALUEEMPTY)) > 0 Then 
			asCols = Split(dicField(F_VALUEEMPTY), ";")
		Else
			asCols = Split(";N/A", ";")
		End If
		If dicField(F_NULLABLE) Then													
			If CStr(dicField(F_VALUE)) = asCols(0) Then									
				sSelected = " CHECKED"													
			Else																		
				sSelected = vbNullString												
			End If																		
			Response.Write _
				"<INPUT TYPE=""RADIO"" CLASS=""gtmControl"" NAME=""" & sFieldName _
				& """ VALUE=""" & asCols(0) & """" + sSelected + ">" _
				& AddFontTag(asCols(1)) & "<BR>" + vbCrLf
		End If																			
		For Each sRow In asRows
			asCols = Split(sRow, ":")
			If asCols(0) = CStr(dicField(F_VALUE)) Then
				sSelected = " CHECKED"
			Else
				sSelected = vbNullString
			End If
			Response.Write "<INPUT TYPE=""RADIO"" CLASS=""gtmControl"" NAME=""" & sFieldName & """ VALUE=""" & asCols(0) & """" + sSelected + ">" & _
				AddFontTag(asCols(1)) & "<BR>" + vbCrLf
		Next
		Exit Sub
	End If
	If sFldType = F_BOOL Then
		If CStr( dicField(F_VALUE) ) = "True"  Then
			sCheckedTrue  = " CHECKED"
			sCheckedFalse = vbNullString
		Else
			sCheckedTrue  = vbNullString
			sCheckedFalse = " CHECKED"
		End If
		Response.Write "<INPUT TYPE=""Radio"" CLASS=""gtmControl"" NAME=""" + sFieldName + """ VALUE=1" + sCheckedTrue + ">Yes" & vbCrlf _
			& "<INPUT TYPE=""Radio"" CLASS=""gtmControl"" NAME=""" + sFieldName + """ VALUE=0" + sCheckedFalse + ">No"
		Exit Sub	
	End If
	Response.Write "<DIV>" & AddFontTag(dicField(F_VALUE)) & "</DIV>"
End Sub

Sub PrintCurrentFields( dicFields )
	Dim sFieldName 
	For Each sFieldName In dicFields
		Response.Write "<TH CLASS=""gtmTh"">" & AddFontTag(dicFields(sFieldName)(F_DESC)) & "</TH>"
	Next
End Sub

Sub SearchData( dicFields )
	Dim sKeyword, asKeywords, sSearchCriteria, rsSearch, sAlign, sFieldName, bDoSearch, sFileLookup
	sSearchCriteria = Request( "txtSearch" )
	bDoSearch = False
	'Build SQL for query
	sSQL = "" _					
		+ "SELECT * " _
		+ "FROM [" + sTable	+ "] WHERE ( "
	asKeywords = Split(sSearchCriteria, " ")
	For Each sFieldName In dicFields
		If dicTables( sTable )( "Fields" )( sFieldName )( F_SEARCHABLE ) Then
			bDoSearch = True
		End If
	Next
	If Not bDoSearch Then
		SendError Err.Number, GTM_NO_SEARCH_FIELDS_SPECIFIED, GTM_NO_SEARCH_FIELDS_MESSAGE, ""
		Exit Sub
	Else
		For Each sKeyword In asKeywords
			sKeyword = Trim(sKeyword)
			If Len(sKeyword) > 0 Then
				For Each sFieldName In dicTables( sTable )( "Fields" )
					If dicTables( sTable )( "Fields" )( sFieldName )( F_SEARCHABLE ) Then
						Select Case dicTables( sTable )( "Fields" )( sFieldName )(F_TYPE)
							Case F_TEXT, F_FILE, F_EMAIL, F_US_PHONE
								sSQL = sSQL + "(" + sFieldName +" LIKE '%" + sKeyword + "%') OR "
							Case F_DATE_MMDDYYYY
								If InStr( sKeyword , "/" ) Then
									If IsDate( sKeyword ) Then
										sSQL = sSQL + "(" + sFieldName +" LIKE #" + sKeyword + "#) OR "
									End If	
								End If	
							Case F_NUMBER, F_BOOL, F_INT
								sSQL = sSQL + "(" + sFieldName +" =" + sKeyword + ") OR "
						End Select
					End If	
				Next
			Else
				Response.Write "<tr valign=top CLASS=""gtmTr""><TH CLASS=""gtmTh"">" + AddFontTag(GTM_HTML_NO_RECS_FOUND) + "</TH></TR>" & vbCrLf 
			End If
		Next
	End If	
	sSQL = Left(sSQL, Len(sSQL)-3) + " ) "
	If Len(dicTables(sTable)(F_RECORDLISTORDER)) > 0 Then 
		sSQL = sSQL + " ORDER BY " + dicTables(sTable)(F_RECORDLISTORDER) 
	End If
	Set rsSearch = Server.CreateObject ( "ADODB.Recordset" )
	rsSearch.ActiveConnection = conDB
	If Not bEnableErrors Then On Error Resume Next
	With rsSearch
		.Open sSQL, , 2,3, &H001
		If .BOF And .EOF Then
			Response.Write "<tr valign=top CLASS=""gtmTr""><TH CLASS=""gtmTh"">" + AddFontTag(GTM_HTML_NO_RECS_FOUND) + "</TH></TR>" & vbCrLf 
		Else
			Response.Write "<tr valign=top CLASS=""gtmTr"">" + vbCrLf 
			PrintCurrentFields( dicFields ) 
			Response.Write "</TR>" & vbCrlf _
				& "<tr valign=top CLASS=""gtmTr"">" & vbCrlf 
			While Not .EOF 
				For Each sFieldName In dicFields
				If dicTables( sTable )( "Fields" )( sFieldName )(F_TYPE) = F_FILE Then
						sFieldLookup = sFieldName
						sFileLookup	 = .Fields (sFieldName)
					End If
					Response.Write "<TD CLASS=""gtmTd""" + sAlign + ">" & AddFontTag(.Fields (sFieldName)) & "</TD>" & vbCrlf
				Next
				Response.Write "<TD CLASS=""gtmTd"">" & _
									AddFontTag( "<A CLASS=""gtmA"" HREF=""" + sPage + "?table=" + Server.URLEncode(sTable) + _
										"&cmd=e&" + KeyURL(rsSearch) + _
										""" TITLE=""" + GTM_EDIT_RECORD +"""><img src=images/edit.gif  border=0></A>  " + _
										
									"<A CLASS=""gtmA"" HREF=""javascript:deleteRecord('" + Replace(Replace(KeyURL(rsSearch), "%27", "'"),"'","\'") + _
									"', OldFile='" & sFileLookup & "', '" & sFieldLookup & "');"" TITLE=""" + GTM_DELETE_RECORD + """><img src=images/delete.gif border=0></A>") + _
								"</TD>" + vbCrLf + _
								"<TD>&nbsp;</TD></TR>" + vbCrlf 
				.MoveNext 
			Wend
		End If
	End With
	On Error Goto 0
End Sub

Function GetCorrectDate(sDate)
	Dim sDateSeparator, sYear, sCentury 
	If Len( sDate ) > 0 Then
	
		If InStr( sDate, "/" ) Then
			sDateSeparator = "/"
		Else
			sDateSeparator = "-"
		End If
		sYear = Mid( sDate, InStrRev( sDate, sDateSeparator) + 1 )
		If Len( sYear  ) = 2 Then 		
			If CInt( sYear ) > 69 Then
				sCentury = "19"
			Else
				sCentury = "20"
			End If
			sDate = Left( sDate, InStrRev( sDate, sDateSeparator) ) + sCentury + sYear
		ElseIf	Len( sYear  ) = 1 Then
			If CInt( sYear ) > 69 Then
				sCentury = "190"
			Else
				sCentury = "200"
			End If
			sDate = Left( sDate, InStrRev( sDate, sDateSeparator) ) + sCentury + sYear
		End If
	Else
		sDate = Date
	End If
	GetCorrectDate = CDate( sDate )
End Function

Function KeyURL(DataSource)
	Dim sFieldName, sKeyValue, sKeyURL
	If DataSource.BOF And DataSource.EOF Then Exit Function
	For Each sFieldName In dicKeyFields
		If Not IsNull(DataSource(sFieldName)) Then
			sKeyValue = DataSource(sFieldName)
		Else
			sKeyValue = vbNullString
		End If
		sKeyURL = sKeyURL & Server.URLEncode("K_" + sFieldName) & "=" & Server.URLEncode(sKeyValue) & "&"
	Next
	If Len(sKeyURL) > 1 Then sKeyURL = Left(sKeyURL, Len(sKeyURL)-1)
	KeyURL = sKeyURL
End Function

Function KeyCriteria
	Dim sFieldName, sKeyCriteria, dicField
	For Each sFieldName In dicKeyFields
		Set dicField = dicKeyFields(sFieldName)
		sKeyCriteria = sKeyCriteria + SQLCriteria(sFieldName, Request("K_" + sFieldName), dicField(F_USEQUOTES), "=") + " AND "
	Next
	If Len(sKeyCriteria) > 5 Then sKeyCriteria = Left(sKeyCriteria, Len(sKeyCriteria)-5)
	KeyCriteria = sKeyCriteria
	
	' TODO Handle Key when a field it's of Date type. 
	' You need to verify the DB provider that you are using in order to get a valid date format and redefine the KeyCriteria.
End Function

Function GetLookupData(sFieldName, sFieldData, dicField)
	Dim sLookupSQL, rsLookup, lFirstSpace, lFirstComma, sFirstField
	If dicField(F_TYPE) = F_SELECT Then sLookupSQL = dicField(F_SOURCE)
	If Len(sLookupSQL) > 0 Then
		lFirstSpace = InStr(1, sLookupSQL, " ") + 1
		lFirstComma = InStr(lFirstSpace, sLookupSQL, ",")
		If lFirstSpace > 1 And lFirstComma > lFirstSpace Then sFirstField = Mid(sLookupSQL, lFirstSpace, lFirstComma-lFirstSpace)
		If Len(sFirstField) = 0 Then 
			GetLookupData = "N/A"
			Exit Function
		End If
		Set rsLookup = conDB.Execute(sLookupSQL)
		With rsLookup
			If IsNull(sFieldData) Or Len(sFieldData) = 0 Then
				GetLookupData = "N/A"
			Else
				On Error Resume Next
				.Filter = SQLCriteria(sFirstField, sFieldData, dicField(F_USEQUOTES), "=")
				If Err.Number = 0 Then
					If Not (.BOF And .EOF) Then
						GetLookupData = CStr(.Fields(1))
					Else
						GetLookupData = "N/A"
					End If
				Else
					RaiseGTMError "GetLookupData", "Couldn't set filter.<p><b>SQL:</b> " & sLookupSQL & "</p><p><b>Filter:</b> " & SQLCriteria(sFirstField, sFieldData, dicField(F_USEQUOTES), "=") & "</p><br>"
					'Response.Write "'" & sFieldData & "' Err: " & Err.number & " " & Err.Description  & "<br>"
					'Response.Write sLookupSQL & "----" & SQLCriteria(sFirstField, sFieldData, dicField(F_USEQUOTES), "=") & "<br>"
					'Response.Flush
				End If
			End If
		End With
	Else
		GetLookupData = sFieldData
	End If
	
	If Len(GetLookupData) = 0 Then GetLookupData = "NULL"
End Function

Sub PrepareToSearch()
	Response.Write vbCrlf _
		&	"<TR><TH CLASS=""gtmTh"" VALIGN=""MIDDLE"">" & vbCrlf _
		&		AddFontTag( langMgr.GetContent("GTM_SEARCH_TITLE", "BackEndMessages", iInterfaceLang) ) & vbCrlf _
		&		"<INPUT CLASS=""gtmControl"" NAME=""txtSearch"" SIZE=""10"" VALUE=""" & Request( "txtSearch" ) & """>" & vbCrlf _
		&		"&nbsp;&nbsp;" & vbCrlf _
		&		"<INPUT TYPE=""HIDDEN"" NAME=""table"" VALUE=""" & sTable & """>" & vbCrlf _
		&		"<INPUT TYPE=""HIDDEN"" NAME=""cmd"" VALUE=""S"">" & vbCrlf _
		&		"<INPUT TYPE=""SUBMIT"" CLASS=""gtmControl"" VALUE=""" & GTM_SEARCH_CAPTION & """>" & vbCrlf _
		&	"</TH></TR>" & vbCrlf
End Sub

Function DeleteOldFile( sPath, sFile )
	Dim obFSO
	Set obFSO = Server.CreateObject ( "Scripting.FileSystemObject" )
	If obFSO.FileExists( Server.MapPath ( sPath + sFile ) ) Then 
		obFSO.DeleteFile ( Server.MapPath( sPath + sFile ) )
	End If
	Set obFSO = Nothing
End Function

' Initialize variables
lPage = Request("page")
If Len(lPage) > 0 Then
	If IsNumeric(lPage) Then 
		lPage = CLng(lPage)
	Else
		lPage = 0
	End If
Else
	lPage = 0
End If
sTable = Request("table")
sCmd = UCase(Request("cmd"))
sPage = Request.ServerVariables("SCRIPT_NAME")
sPage = Mid(sPage, InStrRev(sPage, "/")+1)
Set dicTables = Server.CreateObject("Scripting.Dictionary")

' Populate table definition
%><!-- #include file="tabledef.inc" --><%

' This flag when activated, does not execute "On Error Resume Next" statements.
' Useful when errors arise but you have no idea why they appear. To activate the
' flag, pass something in the "err" querystring variable.
bEnableErrors = Len(Request("err")) > 0

GTMMain

Sub GTMMain()
	Set rsStoringDate = Server.CreateObject ( "ADODB.Recordset" )
	rsStoringDate.ActiveConnection = conDB
	bShowSearchForm = False
	' Do some parsing
	If Len(sCmd) > 0 Then
		Set dicWorkFields = Server.CreateObject("Scripting.Dictionary")
		Set dicKeyFields = Server.CreateObject("Scripting.Dictionary")

		On Error Resume Next	
		For Each sFieldName In dicTables(sTable)("Fields")
			Set dicField = dicTables(sTable)("Fields")(sFieldName)
			RaiseGTMError "GTMMain", "Cannot get reference to field: " & sTable & "." & sFieldName			
		   	If (sCmd="E" Or dicField(F_INLIST)) And (dicField(F_TYPE) <> F_ONETOMANY) Then
		   		sFields = sFields + sFieldName + ","
		 		dicWorkFields.Add sFieldName, dicField
		 	End If
		 	If dicField(F_ISKEY) Then
		 		dicKeyFields.Add sFieldName, dicField
		 	End If
		 	dicField(F_VALUE) = Request(sFieldName)
		Next
		
		If Len(sFields) > 1 Then sFields = Left(sFields, Len(sFields)-1)
		
		Set dicField = Nothing
	End If
	Select Case sCmd
		Case "A", "E"	' New or edit forms
			Dim sNextCmd, sButtonCaption
			
			Select Case sCmd
				Case "A" 
					sNextCmd = "C"
					sButtonCaption = GTM_CREATE_CAPTION
				Case "E"
					sNextCmd = "U"
					sButtonCaption = GTM_EDIT_CAPTION
					sSQL = "SELECT " + sFields + " FROM [" + sTable + "] WHERE " + KeyCriteria

					If Not bEnableErrors Then On Error Resume Next
					rsData.Open sSQL
				
					If Err.Number <> 0 Then
						SendError Err.Number, Err.Description, "Trying to find a record.", sSQL
						Exit Sub
					End If
					On Error Goto 0
				
					If rsData.BOF And rsData.EOF Then
						Response.Write GTM_HTML_NO_RECS_FOUND + "<BR>" + sSQL
					Else
						For Each sFieldName In dicTables(sTable)("Fields")
							If dicTables(sTable)("Fields")(sFieldName)(F_TYPE) <> F_ONETOMANY Then
								If Not IsNull(rsData(sFieldName)) Then
									dicTables(sTable)("Fields")(sFieldName)(F_VALUE) = _
										CStr(rsData(sFieldName))
								End If
							End If
						Next
					End If
			End Select
			%>
			<% If bolDisplayNewEditor Then %>
				<script language="JavaScript" src="common/htmleditor/scripts/editor.js"></script>
			<% Else%>
				<SCRIPT SRC="common/htmleditor2/htmleditorres.js"></SCRIPT>
			<% End if%>
			<SCRIPT LANGUAGE="JavaScript">
			<!--
			function isFieldEmpty(poField, psCaption) {
				if (poField.value=="") {
					alert(psCaption);
					poField.focus();
					return false;
				}
					return true;
			}
			function isFieldNumber(poField, psCaption) {
				if (isNaN(poField.value)) {
					alert(psCaption);
					poField.focus();
					return false;
				} else
					return true;
			}
			function isFieldInteger(poField, psCaption) {
				if (!isNaN(poField.value)) {
					if(!poField.value.indexOf(".")<0) {
						alert(psCaption);
						poField.focus();
						return false ;
					} else 
						return true ;
				} else {
					alert(psCaption);
					poField.focus();
					return false;
				}
			}
			function isFieldEmailAddress(poField, psCaption) {
				re = /.+@.+\..+/ ;
							
				if (!re.test(poField.value)) {
					alert(psCaption);
					poField.focus();
					return false;
				} else
					return true;
			}
			
			function isDate(poDate, psMessage) {
				var arrayOfStrings, sDelimiter,  bReturn;
				var iYear, iMonth, iDay;
				
				if ( poDate.value.indexOf( "/" ) != "-1" ) 
					sDelimiter = "/";	
				else
					sDelimiter = "-";

				if (poDate.value.length == 0) return true;
				bReturn = true;
				// Parse yyyy, mm, dd from string
				arrayOfStrings = poDate.value.split( sDelimiter )
				iMonth = parseInt(arrayOfStrings[0], 10);
				iDay   = parseInt(arrayOfStrings[1], 10);
				iYear  = parseInt(arrayOfStrings[2], 10);
				
				if (iYear == 0){
				  iYear =2000
				}
				
				if (isNaN(iYear) || isNaN(iMonth) || isNaN(iDay)) {
					bReturn = false;
				}
				if (iDay > 31 || iDay < 1 || iMonth < 1 || iMonth > 12 || iYear < 1) {
					bReturn = false;
				}
				if (iDay == 31 && "_1_3_5_7_8_10_12_".indexOf("_"+iMonth+"_") == -1 ) {
					bReturn = false;
				}
				if (iDay == 30 && iMonth == 2) {
					bReturn = false;
				}
				if (iDay == 29 && iMonth == 2 && !isLeapYear(iYear)) {
					bReturn = false;
				}
				if (!bReturn && trim(psMessage).length > 0){	
					alert(psMessage);
					poDate.focus();
					poDate.select();
				}	
				return bReturn;
			}

			function isTime(poField, psCaption) {
				var sTimeValue, iHour, iMinute;
				sTimeValue = poField.value;
			
				switch( sTimeValue.length ) {
					// Create a valid Regular Expression and get hour and minute data
					case 8:
						re = /((\d\d:\d\d)\b am|pm)/i ;	
						iHour	= sTimeValue.charAt(0) + sTimeValue.charAt(1);
						iMinute = sTimeValue.charAt(3) + sTimeValue.charAt(4);
						break;
					case 7:
						re = /((\d:\d\d)\b am|pm)/i ;
						iHour	= sTimeValue.charAt(0) 
						iMinute = sTimeValue.charAt(2) + sTimeValue.charAt(3);
						break;
					default:
						alert(psCaption);
						poField.focus();
						return false;
				}
				
				if (!re.test(poField.value)) {
					alert(psCaption);
					poField.focus();
					return false;
				} else {
					if(iHour>23 || iMinute>59 )
					{
						alert(psCaption);
						poField.focus();
						return false;
					}
					else
						return true;
				} 
			}

			
			function isLeapYear(piYear) {
				if (((piYear % 4 == 0) && piYear % 100 != 0) || piYear % 400 == 0)
					return true;
				else
					return false;
			}
			function trim(pString){
			  var iStart, iEnd;
			  var sTrimmed = "";
			  var cChar;
				  
			  // Return empty sting if parameter is undefined
			  if (pString==null)
				return sTrimmed;

			  iEnd = pString.length - 1;
			  iStart = 0;
			  bLoop = true;
			  cChar = pString.charAt(iStart);
			  while ((iStart < iEnd) && ((cChar == "\n") || (cChar == "\r") ||
			                            (cChar == "\t") || (cChar == " ") || (cChar == "'")  )){
			     iStart ++;
			     cChar = pString.charAt(iStart);
			  }
			  cChar = pString.charAt(iEnd);
			  while ((iEnd >= 0) && ((cChar == "\n") || (cChar == "\r") ||
			                        (cChar == "\t") || (cChar == " ") || (cChar == "'")  )){
			     iEnd-=1;
			     cChar = pString.charAt(iEnd);
			  }
			  if (iStart <= iEnd){
			     sTrimmed = pString.substring(iStart, iEnd + 1);
			  } else {
			     sTrimmed = "";
			  }
				return sTrimmed;
			}
			function isUSPhone(poField, psCaption) {
				re = /\(?\d{3}\)?([-\/\. ])\d{3}\1|[-\/\. ]\d{4}/ ;
				if (!re.test(poField.value)) {
					alert(psCaption);
					poField.focus();
					return false;
				} else
					return true;
			}
			
			function validateForm(pForm) {
				bReturn = true ;
				<%
				For Each sFieldName In dicTables(sTable)("Fields")
					Set dicField = dicTables(sTable)("Fields")(sFieldName)
					If Not dicField(F_HIDDEN) And Not (sCmd="E" And dicField(F_ISKEY)) Then
						If Not dicField(F_NULLABLE) Then
							Response.Write "bReturn = bReturn && isFieldEmpty(pForm." + sFieldName + ", """ + GTM_IS_EMPTY + """);" + vbCrLf
						End If
						Select Case dicField(F_TYPE)
							Case F_NUMBER
								Response.Write "bReturn = bReturn && isFieldNumber(pForm." + sFieldName + ", """ + GTM_ISNT_NUMBER + """);" + vbCrLf
							Case F_INT
								Response.Write "bReturn = bReturn && isFieldInteger(pForm." + sFieldName + ", """ + GTM_ISNT_INTEGER + """);" + vbCrLf
							Case F_EMAIL
								Response.Write "bReturn = bReturn && isFieldEmailAddress(pForm." + sFieldName + ", """ + GTM_ISNT_EMAIL + """);" + vbCrLf
							Case F_DATE_MMDDYYYY
								Response.Write "bReturn = bReturn && isDate(pForm." + Replace( sFieldName, " " ,"" ) + ", """ + GTM_ISNT_DATE + """);" + vbCrLf
							Case F_US_PHONE
								Response.Write "bReturn = bReturn && isUSPhone(pForm." + Replace( sFieldName, " " ,"" ) + ", """ + GTM_ISNT_US_PHONE + """);" + vbCrLf
							Case F_TIME_HHMM
								Response.Write "bReturn = bReturn && isTime(pForm." + Replace( sFieldName, " " ,"" ) + ", """ + BTU_ISNT_TIME + """);" + vbCrLf
						End Select
					End If
				Next
				%>
				return bReturn ;
			}
			function UploadFile( psField, psPath ) {
				var sFeatures;
				sFeatures = "toolbar=no,location=no,directories=no,status=no,menubar=no, scrollbars=no,resizeable=no,width=400,height=110,top=" + ( screen.width / 2 - 215 ) + ",left=" + ( screen.height / 2 - 85 ) ;
				open("common/gtm/uploadForm.asp?Field=" + psField + "&Path=" + escape( psPath ) , "Upload", sFeatures );
			}
			function SelectFile( psField, psPath ) {
				var sFeatures;
				sFeatures = "toolbar=no,location=no,directories=no,status=no,menubar=no,scrollbars=yes,resizeable=no,width=550,height=330,top=" + ( screen.width / 2 - 215 ) + ",left=" + ( screen.height / 2 - 115 ) ;
				open( "common/gtm/selectForm.asp?Table=<%=Server.URLEncode(sTable)%>&Field=" + psField + "&Path=" + escape( psPath ) , "Select", sFeatures );
			}
			function ViewFile( psField, psFile, psPath ) {
				if( psField != "" )
					open( psPath + psFile, "Preview" );
				else
					alert( "<%=GTM_PREVIEW_ALERT%>" );
			}
			//-->
			</SCRIPT>
			<SCRIPT>
				<!--
					var htmlContent;
					function preProcess(form) {
						<%
						Dim iCounter
						Dim strJsMethod
						iCounter = 1
						
						If bolDisplayNewEditor Then 
							strJsMethod =".getHTMLBody();"
						Else
							strJsMethod =".getHtml();"
						End If
						For Each sFieldName In dicTables(sTable)("Fields")
							Set dicField = dicTables(sTable)("Fields")(sFieldName)
							Select Case dicField(F_TYPE)
								Case F_HTML_FORMAT 
									Response.Write "form." & sFieldName & ".value = htmlContent" & iCounter & strJsMethod
							End Select
							iCounter = iCounter + 1
						Next
						%>
						return validateForm(form);
					}

		
					function initEditors() {
						<%
						If Not bolDisplayNewEditor Then 
						Dim iContent
						iContent = 1
						For Each sFieldName In dicTables(sTable)("Fields")
						Set dicField = dicTables(sTable)("Fields")(sFieldName)
							Select Case dicField(F_TYPE)
								Case F_HTML_FORMAT 
									Response.Write "htmlContent"& iContent & " = new HtmlEditor(""" & sFieldName & """);" 
									Response.Write "htmlContent"& iContent & ".setHtml(document.forms[0]." & sFieldName & ".value);" 
							End Select
							iContent = iContent + 1
						Next
						End If
						%>
					}
				//-->
			</SCRIPT>

			<FORM CLASS="gtmForm" METHOD="POST" ACTION="<%=sPage%>" ONSUBMIT="return preProcess(this);" NAME="frmGTM">
				<INPUT TYPE="hidden" NAME="cmd" VALUE="<%=sNextCmd%>">
				<INPUT TYPE="hidden" NAME="table" VALUE="<%=sTable%>">
				<INPUT TYPE="hidden" NAME="err" VALUE="<%=bEnableErrors%>">
				<%For Each sFieldName In dicKeyFields%>
				<INPUT TYPE="hidden" NAME="K_<%=sFieldName%>" VALUE="<%=dicKeyFields(sFieldName)(F_VALUE)%>">
				<%Next
				If sCmd = "A" Then
					If Len(Trim(dicTables(sTable)(F_NEWMSG)))>0 Then
						Response.Write vbCrLf _
							& "<TABLE CLASS=""gtmTable"" BORDER=""0"" CELLSPACING=""0"" CELLPADDING=""0"">" & vbCrLf _
							&	"<tr valign=top CLASS=""gtmTr"">" & vbCrLf _
							&		"<TD CLASS=""gtmTableTitle"">" & vbCrLf _
							&			dicTables(sTable)(F_NEWMSG) & vbCrLf _
							& 		"</TD>" & vbCrLf _
							& 	"</TR>" & vbCrLf 

						If Len(Trim(dicTables(sTable)(F_RECORDEDITTEXT))) > 0 Then
							Response.Write "" _
								&	"<tr valign=top CLASS=""gtmTr"">" & vbCrLf _
								&		"<TD CLASS=""gtmTd"">" & vbCrLf _
								&			"<BR><BLOCKQUOTE>" & dicTables(sTable)(F_RECORDEDITTEXT) & "</BLOCKQUOTE>" & vbCrLf _
								&		"</TD>" & vbCrLf _
								&	"</TR>"
						End If

						Response.Write "" _
							& 	"<tr valign=top CLASS=""gtmTr"">" & vbCrLf _
							&		"<TD CLASS=""gtmSectionContentOut"" ONMOUSEOVER=""this.className='gtmSectionContentOver';""" _
							&			"ONMOUSEOUT=""this.className='gtmSectionContentOut';"">" & vbCrLf 
					End If
				ElseIf sCmd = "E" Then
					If Len(Trim(dicTables(sTable)(F_EDITMSG)))>0 Then
						Response.Write vbCrLf _
							& "<TABLE CLASS=""gtmTable"" BORDER=""0"" CELLSPACING=""0"" CELLPADDING=""0"">" & vbCrLF _
							&	"<tr valign=top CLASS=""gtmTr"">" & vbCrLf _
							&		"<TD CLASS=""gtmtabletitle"">" & vbCrLf _
							&			dicTables(sTable)(F_EDITMSG) & vbCrLf _
							&		 "</TD>" & vbCrLf 

						If Len(Trim(dicTables(sTable)(F_RECORDEDITTEXT))) > 0 Then
							Response.Write "" _
								&	"<tr valign=top CLASS=""gtmTr"">" & vbCrLf _
								&		"<TD CLASS=""gtmTd"">" & vbCrLf _
								&			"<BR><BLOCKQUOTE>" & dicTables(sTable)(F_RECORDEDITTEXT) & "</BLOCKQUOTE>" & vbCrLf _
								&		"</TD>" & vbCrLf _
								&	"</TR>"
						End If

						Response.Write "" _							
							&	"</TR>" & vbCrLf _
							&	"<tr valign=top CLASS=""gtmTr"">" & vbCrLf _
							&		"<TD CLASS=""gtmSectionContentOut"" ONMOUSEOVER=""this.className='gtmSectionContentOver';""" _
							&			"ONMOUSEOUT=""this.className='gtmSectionContentOut';"">" & vbCrLf 
							
					End If
				End If
				Response.Write "<TABLE CLASS=""gtmtable"" WIDTH=""100%"" BORDER=""0"">" & vbCrLf
				iHTMLCounter = 1  ' Required for the F_HTML_FORMAT flag
				For Each sFieldName In dicTables(sTable)("Fields")
					Set dicField = dicTables(sTable)("Fields")(sFieldName)
					If Not dicTables( sTable )( "Fields" )( sFieldName )( F_HIDDEN ) Then
						If dicField(F_ISKEY) And sCmd = "E" Then
							Response.Write vbCrLf _
								& "<TR>" & vbCrLf _
								&	"<TD CLASS=""gtmCaption"" VALIGN=""top"" BGCOLOR=""" + sGTMFieldBG + """>" & vbCrLf _
								&		AddFontTag(dicField(F_DESC) & " <FONT CLASS=""gtmHintText"">" & dicField(F_HINTTEXT) & "</FONT>") & vbCrLf _ 
								&  	"</TD>" & vbCrLf _
								& 	"<TD CLASS=""gtmTd"">" 'CAMP

							If dicField(F_UPDATABLE) Then
								PaintField sFieldName, dicField
							Else
								If dicField(F_TYPE) = F_SELECT Then 'CAMP
									Set rsComboLookup = conDB.Execute(dicField(F_SOURCE))
									If dicField(F_USEQUOTES) Then
										rsComboLookup.Filter = rsComboLookup(0).Name & "='" & dicField(F_VALUE) & "'"
									Else
										rsComboLookup.Filter = rsComboLookup(0).Name & "=" & dicField(F_VALUE)
									End If
									Response.Write "<B>" + AddFontTag(rsComboLookup(1).Value) + "</B>"
								Else
									Response.Write "<B>" + AddFontTag(dicField(F_VALUE)) + "</B>"
								End If
							End If
							Response.Write vbCrLf _
									& 	"</TD>" & vbCrLf _
									& "</TR>" & vbCrLf
						Else
							Response.Write vbCrLf _
								& "<TR>" & vbCrLf _
								&	"<TD CLASS=""gtmCaption"" VALIGN=""top"" BGCOLOR=""" + sGTMFieldBG + """>" & vbCrLf _
								&		AddFontTag(dicField(F_DESC) & " <FONT CLASS=""gtmHintText"">" & dicField(F_HINTTEXT) & "</FONT>") & vbCrLf _
								&	"</TD>" & vbCrLf _
								&	"<TD CLASS=""gtmTd"">" 
									
							PaintField sFieldName, dicField
						End If
					End If	
					iHTMLCounter = iHTMLCounter + 1
				Next
				%>
				<tr valign=top CLASS="gtmTr">
					<TD COLSPAN="2" CLASS="gtmTd">
						<INPUT CLASS="gtmControl" TYPE="SUBMIT" VALUE="<%=sButtonCaption%>" id=SUBMIT1 name=SUBMIT1>
					</TD>
				</TR>
				</TABLE>
				<%
				If Len(Trim(dicTables(sTable)(F_NEWMSG)))>0 Or Len(Trim(dicTables(sTable)(F_EDITMSG)))>0 Then
					Response.Write vbCrLf _
						&		"</TD>" & vbCrLf _
						&	"</TR>" & vbCrLf _
						& "</TABLE>"
				End If
				%>
			</FORM>
			<%	
		Case "V"			' View record
			sSQL = "SELECT * FROM [" + sTable + "] WHERE " + KeyCriteria

			If Not bEnableErrors Then On Error Resume Next
			rsData.Open sSQL
				
			If Err.Number <> 0 Then
				SendError Err.Number, Err.Description, "Trying to find a record.", sSQL
				Exit Sub
			End If
			On Error Goto 0
				
			If rsData.BOF And rsData.EOF Then
				Response.Write GTM_HTML_NO_RECS_FOUND + "<BR>" + sSQL
			Else
				For Each sFieldName In dicTables(sTable)("Fields")
					If Not IsNull(rsData(sFieldName)) Then
						dicTables(sTable)("Fields")(sFieldName)(F_VALUE) = _
							CStr(rsData(sFieldName))
					End If
				Next
			End If
			sButtonCaption = GTM_CLOSE_CAPTION
			Response.Write "<TABLE CLASS=""gtmtable"" WIDTH=""100%"" BORDER=""0"">" & vbCrLf
			iHTMLCounter = 1  ' Required for the F_HTML_FORMAT flag
			For Each sFieldName In dicTables(sTable)("Fields")
				Set dicField = dicTables(sTable)("Fields")(sFieldName)
				If Not dicTables( sTable )( "Fields" )( sFieldName )( F_HIDDEN ) Then
					If dicField(F_ISKEY) And sCmd = "E" Then
						Response.Write vbCrLf _
							& "<TR>" & vbCrLf _
							&	"<TD CLASS=""gtmCaption"" VALIGN=""top"" BGCOLOR=""" + sGTMFieldBG + """>" & vbCrLf _
							&		AddFontTag(dicField(F_DESC) & " <FONT CLASS=""gtmHintText"">" & dicField(F_HINTTEXT) & "</FONT>") & vbCrLf _ 
							&  	"</TD>" & vbCrLf _
							& 	"<TD CLASS=""gtmTd"">" 'CAMP

						If dicField(F_UPDATABLE) Then
							PaintViewField sFieldName, dicField
						Else
							If dicField(F_TYPE) = F_SELECT Then 'CAMP
								Set rsComboLookup = conDB.Execute(dicField(F_SOURCE))
								If dicField(F_USEQUOTES) Then
									rsComboLookup.Filter = rsComboLookup(0).Name & "='" & dicField(F_VALUE) & "'"
								Else
									rsComboLookup.Filter = rsComboLookup(0).Name & "=" & dicField(F_VALUE)
								End If
								Response.Write "<B>" + AddFontTag(rsComboLookup(1).Value) + "</B>"
							Else
								Response.Write "<B>" + AddFontTag(dicField(F_VALUE)) + "</B>"
							End If
						End If
						Response.Write vbCrLf _
								& 	"</TD>" & vbCrLf _
								& "</TR>" & vbCrLf
					Else
						Response.Write vbCrLf _
							& "<TR>" & vbCrLf _
							&	"<TD CLASS=""gtmCaption"" VALIGN=""top"" BGCOLOR=""" + sGTMFieldBG + """>" & vbCrLf _
							&		AddFontTag(dicField(F_DESC) & " <FONT CLASS=""gtmHintText"">" & dicField(F_HINTTEXT) & "</FONT>") & vbCrLf _
							&	"</TD>" & vbCrLf _
							&	"<TD CLASS=""gtmTd"">" 
										
						PaintViewField sFieldName, dicField
					End If
				End If	
				iHTMLCounter = iHTMLCounter + 1
			Next
			%>
			<tr valign=top CLASS="gtmTr">
				<TD COLSPAN="2" CLASS="gtmTd">
					<INPUT CLASS="gtmControl" TYPE="BUTTON" VALUE="<%=sButtonCaption%>" ONCLICK="javascript:window.history.back()" id=BUTTON1 name=BUTTON1>
				</TD>
			</TR>
			</TABLE>
			<%			
		Case "C", "U"		' Update record
			Dim bHasOneToMany, asOneToManyValues, sOneToManyValue, asOneToManySource, sInsertKeyValue
			Dim bUniqueFieldError, sOffendingField, sOperation
			
			' Check unique fields 
			bUniqueFieldError = False
			sOffendingField = ""
			sOperation = ""
			For Each sFieldName In dicTables(sTable)("Fields")
				If dicTables(sTable)("Fields")(sFieldName)(F_UNIQUE) Then
					' Check if this value exists
					sSQL = "SELECT COUNT(" & sFieldName & ") FROM " & sTable & " WHERE " & sFieldName & "="
					If dicTables(sTable)("Fields")(sFieldName)(F_USEQUOTES) Then
						sSQL = sSQL & "'" & Request(sFieldName) & "'"
					Else
						sSQL = sSQL & Request(sFieldName)
					End If
					iCount = conDB.Execute(sSQL)(0)
					
					sOffendingField = sFieldName
					If sCmd = "C" And iCount > 0 Then 
						bUniqueFieldError = True 
						sOperation = "add"
						Exit For
					ElseIf sCmd = "U" And iCount > 1 Then
						bUniqueFieldError = False
						sOperation = "update"
						Exit For
					End If
				End If
			Next
			If bUniqueFieldError Then
			%>
			<div>
			<font face=Tahoma size=2>
			<p><font size=+1><b>Cannot <%=sOperation%> this record</b></font></p>
			<p>GTM couldn't not <%=sOperation%> this record because the <b><%=sOffendingField%></b> contains [<b><%=Request(sFieldName)%></b>] and 
			this table cannot have two records with the same value for this field. Please go <a href="javascript:history.back();">back</a> and edit this field and
			try again.</p>
			</font>			
			</div>
			<%
			Response.End
			End If

			' Initialize variable that signals that at least one one-to-many field was found
			bHasOneToMany = False
		
			If Not bEnableErrors Then On Error Resume Next	
			With rsData
	 			.Open sTable, , 2, 3 ' adOpenDynamic, adLockOptimistic
				If Err.Number <> 0 Then
					SendError Err.Number, Err.Description, "Trying to create/update a record.", sTable
					Exit Sub
				End If
				If sCmd = "C" Then
					.AddNew
					For Each sFieldName In dicKeyFields
						If Not dicKeyFields(sFieldName)(F_AUTOGEN) Then 
							.Fields(sFieldName) = dicKeyFields(sFieldName)(F_VALUE) 'CAMP
						End If
					Next
					If dicTables(sTable)(F_FILTERBYLANG) Then
						.Fields("LangID") = iContentLang
					End If
				Else
					.Filter = KeyCriteria
				End If
				
				' Prepare regular expression to adjust image paths on HTML fields
				Set re = New RegExp
				re.IgnoreCase = True
				re.Multiline = True
				re.Global = True
				
				For Each sFieldName In dicTables(sTable)("Fields")
					If dicTables(sTable)("Fields")(sFieldName)(F_UPDATABLE) Then
						' Detect HTML fields to adjust image paths
						sFieldValue = Request(sFieldName)
						If dicTables(sTable)("Fields")(sFieldName)(F_TYPE) = F_HTML_FORMAT Then
							re.Pattern = "http:[^>]+/" + dicTables(sTable)("Fields")(sFieldName)(F_SOURCE) + "/"
							sFieldValue = re.Replace(sFieldValue, dicTables(sTable)("Fields")(sFieldName)(F_SOURCE) + "/")

							re.Pattern = "\.\./" + dicTables(sTable)("Fields")(sFieldName)(F_SOURCE) + "/"
							sFieldValue = re.Replace(sFieldValue, dicTables(sTable)("Fields")(sFieldName)(F_SOURCE) + "/")

							re.Pattern = "http[^""]+/admin/content.asp[^#]+#"
							sPageContent = re.Replace(sPageContent, "#")
		
							re.Pattern = "http[^""]+/admin/"
							sPageContent = re.Replace(sPageContent, "")

							re.Pattern = sPathToTrimPattern		
							sPageContent = re.Replace(sPageContent, "")
		
							re.Pattern = "admin/"
							sPageContent = re.Replace(sPageContent, "")
							sPageContent = Replace(sPageContent, IMAGE_FOLDER, IMAGE_FOLDER_TRANSFORMED)
						End If

						If Len(sFieldValue) = 0 Then
							If dicTables(sTable)("Fields")(sFieldName)(F_TYPE) = F_SELECT And _
								dicTables(sTable)("Fields")(sFieldName)(F_NULLABLE) And _
								Len(dicTables(sTable)("Fields")(sFieldName)(F_VALUEEMPTY)) > 0 Then
								rsData(sFieldName) = Split(dicTables(sTable)("Fields")(sFieldName)(F_VALUEEMPTY), ";")(0)
							Else
								rsData(sFieldName) = Null
							End If
						Else
							rsData(sFieldName) = sFieldValue
						End If
					End If
					If dicTables(sTable)("Fields")(sFieldName)(F_TYPE) = F_ONETOMANY Then bHasOneToMany = True				
				Next
				.Update
				
				' Get autogenerated values
				If sCmd = "C" Then
					For Each sFieldName In dicKeyFields
						If dicKeyFields(sFieldName)(F_AUTOGEN) Then 
							dicKeyFields(sFieldName)(F_VALUE) = .Fields(sFieldName)
						End If
					Next
				End If
				
				For Each sFieldName In dicTables(sTable)("Fields")
					If dicTables(sTable)("Fields")(sFieldName)(F_UPDATABLE) Then
						If dicTables(sTable)("Fields")(sFieldName)(F_TYPE) = F_DATE_MMDDYYYY Then
							If Len(Request(sFieldName)) > 0  Then
								sSQL = "SELECT * FROM [" + sTable + "] WHERE " + KeyCriteria 
								rsStoringDate.Open sSQL, , 1, 2, 1
								If Not (rsStoringDate.BOF And rsStoringDate.EOF) Then
									rsStoringDate.Fields(dicTables(sTable)("Fields")(sFieldName)(F_FIELD_NAME)) = GetCorrectDate(Request(sFieldName))
									rsStoringDate.Update 
								End If
							Else
								rsData(sFieldName) = Date
							End If	
						End If
					End If
				Next
				
				' Process one to many relation ships
				If bHasOneToMany Then
					For Each sFieldName In dicTables(sTable)("Fields")
						If dicTables(sTable)("Fields")(sFieldName)(F_TYPE) = F_ONETOMANY Then
							asOneToManySource = Split(dicTables(sTable)("Fields")(sFieldName)(F_SOURCE), ";")
							asOneToManyValues = Split(Trim(dicTables(sTable)("Fields")(sFieldName)(F_VALUE)), ",")
							
							If sCmd = "U" Then
								sSQL = "DELETE FROM [" + asOneToManySource(0) + "] WHERE " + KeyCriteria
								conDB.Execute sSQL
							End If
							
							For Each sOneToManyValue In asOneToManyValues
								If sCmd = "C" Then
									sInsertKeyValue = dicKeyFields(asOneToManySource(1))(F_VALUE)
								Else
									sInsertKeyValue = Request("K_" + asOneToManySource(1))
								End If
								sOneToManyValue = Trim(sOneToManyValue)
								sSQL = "INSERT INTO [" + asOneToManySource(0) + "] (" + asOneToManySource(1) + "," + asOneToManySource(2) + ") VALUES (" & sInsertKeyValue & "," & sOneToManyValue & ")"
								conDB.Execute sSQL
							Next
							
						End If
					Next
				End If
				
				Err.Clear 
				If Err.number <> 0 Then
					SendError Err.number, Err.Description, "Trying to create/update a record.", sTable
					Exit Sub
				End If
			End With
			On Error Goto 0
			Response.Redirect sPage + "?cmd=r&table=" + Server.URLEncode(sTable)
		Case "D"		' Delete
			' Build SQL statement
			sSQL = "DELETE FROM [" + sTable + "] WHERE " + KeyCriteria
			
			If Not bEnableErrors Then On Error Resume Next
			conDB.Execute sSQL
			
			If Len( Request( "oldFile" ) ) > 0 Then
				' file storage query
				sQuery = "SELECT " + Request( "field" ) + " FROM [" + sTable + "] WHERE " + Request( "field" ) + "='" + Request( "oldFile" ) + "'"
				' Check if another record uses the old file
				Set cmdIsSafeToDelete = conDB.Execute( sQuery )
				If ( cmdIsSafeToDelete.BOF And cmdIsSafeToDelete.EOF )  Then
					' Delete previous file
					DeleteOldFile Request( "Path" ), Request( "oldFile" ) 
				End If
			End If	
			If Err.Number <> 0 Then
				SendError Err.Number, Err.Description, "Trying to delete a record.", sSQL
				Exit Sub
			End If
			Response.Redirect sPage + "?cmd=r&table=" + Server.URLEncode(sTable)
		Case "R", "S"		' Retrieve, Search
			Dim sAlign
		%>
		<SCRIPT>
			<!--
			function isFieldEmpty(poField, psCaption) {
				if (poField.value=="") {
					alert(psCaption);
					poField.focus();
					return false;
				}
					return true;
			}
			function deleteRecord( sKey, sOldFile, sField, sPath ) {
				if ( confirm("<%=GTM_CONFIRM_REC_DELETE%>") ) {
					document.location.href = "<%=sPage%>?table=<%=Server.URLEncode(sTable)%>&cmd=d&" + sKey + "&oldFile=" + sOldFile + "&field=" + sField + "&Path=" + sPath ;
				}
			}
			function ValidateSearch( pForm ) {
				var bReturn;
				bReturn = true;
				bReturn = bReturn && isFieldEmpty( pForm.txtSearch, "<%=GTM_NO_SEARCH_TERM%>" );
				return bReturn;
			}
			//-->
		</SCRIPT>
		<%
			Response.Write vbCrLf _
				& "<FORM NAME=""frmMain"" ACTION=""" & sPageName & """ onSubmit=""return ValidateSearch( this );"">" & vbCrLf _
				& "<TABLE CLASS=""gtmTable"" BORDER=""0"" CELLSPACING=""0"" CELLPADDING=""0"">" & vbCrLf _
				&	"<tr valign=top CLASS=""gtmTr"">" & vbCrLf _
				&		"<TD CLASS=""gtmTableTitle"">" & vbCrLf _
				&			"&nbsp;&nbsp;&nbsp;" & AddFontTag(dicTables(sTable)(F_DESC)) & "&nbsp;&nbsp;&nbsp;" & vbCrLf _
				&		"</TD>" & vbCrLf _
				&	"</TR>"
				
			If Len(dicTables(sTable)(F_RECORDLISTTEXT)) > 0 Then
				Response.Write "" _
					&	"<tr valign=top CLASS=""gtmTr"">" & vbCrLf _
					&		"<TD CLASS=""gtmTd"">" & vbCrLf _
					&			"<BR><BLOCKQUOTE>" & AddFontTag(dicTables(sTable)(F_RECORDLISTTEXT)) & "</BLOCKQUOTE>" & vbCrLf _
					&		"</TD>" & vbCrLf _
					&	"</TR>"
			End If

			For Each sFieldName In dicTables(sTable)("Fields")
				If dicTables(sTable)("Fields")(sFieldName)(F_SEARCHABLE) Then
					bShowSearchForm = True
				End If
			Next	
				
			If bShowSearchForm Then PrepareToSearch
			Response.Write vbCrlf _
			&	"<tr valign=top CLASS=""gtmTr"">" & vbCrLf _
			&		"<TD CLASS=""gtmSectionContentOut"" ONMOUSEOVER=""this.className='gtmSectionContentOver';""" _
			&			"ONMOUSEOUT=""this.className='gtmSectionContentOut';"">" & vbCrLf _
			& 			"<TABLE CLASS=""gtmInnerTable"">" + vbCrLf 

			If sCmd = "S" Then
				SearchData( dicWorkFields )
			Else
				If dicTables(sTable)(F_FILTERBYLANG) Then 
					sLangFilter = " WHERE LangID = " & iContentLang
				End If
				
				' Retrieve records from database
				sSQL = "SELECT " + sFields + " FROM [" + sTable	+ "]" & sLangFilter
				If Len(dicTables(sTable)(F_RECORDLISTORDER)) > 0 Then 
					sSQL = sSQL + " ORDER BY " + dicTables(sTable)(F_RECORDLISTORDER) 
				End If
				
				With rsData
					On Error Resume Next
					.Open sSQL
					If Err.number <> 0 Then
						SendError Err.number, Err.Description, "Trying to retrieve records.", sTable
						Exit Sub
					End If
					On Error Goto 0
			
					If .BOF And .EOF Then
				 		Response.Write "<tr valign=top CLASS=""gtmTr""><TH CLASS=""gtmTh"">" + AddFontTag(GTM_HTML_NO_RECS_FOUND) + "</TH></TR>" & vbCrLf 
				 	Else
				 		Response.Write "<tr valign=top CLASS=""gtmTr"">" + vbCrLf
				 		PrintCurrentFields( dicWorkFields )
				 		' Initialize counters
				 		lRecIndex = 0
		 				If lGTMRecsPerPage > 1 Then
							If lPage > 0 Then
								.Move CLng(lPage * lGTMRecsPerPage)
							End If
							bBOF = (lPage = 0)
						End If
						While (Not .EOF And (lRecIndex < lGTMRecsPerPage))
							Response.Write "<TR VALIGN=top>" + vbCrLf
		 					For Each sFieldName In dicWorkFields
					 			If Not dicWorkFields(sFieldName)(F_USEQUOTES) And Len(dicWorkFields(sFieldName)(F_SOURCE)) = 0 Then
									sAlign = " ALIGN=""right"""
								Else
									sAlign = ""
								End If
		 						If dicTables( sTable )( "Fields" )( sFieldName )(F_TYPE) = F_FILE Then
									sFieldLookup = sFieldName
									sFileLookup	 = .Fields (sFieldName)
									sFilePath	 = dicTables( sTable )( "Fields" )( sFieldName )( F_FILEPATH )
								End If
		 						Response.Write "<TD CLASS=""gtmTd""" + sAlign + ">" & AddFontTag(GetLookupData(sFieldName, rsData(sFieldName), dicWorkFields(sFieldName))) & "</TD>" 
							Next
							Response.Write "<TD CLASS=""gtmTd"">" 
							
							If CheckAction(sTable, F_SECEDIT) Then
								Response.Write "" _
									+ "<A CLASS=""gtmA"" HREF=""" + sPage + "?table=" + Server.URLEncode(sTable) _
									+ "&cmd=e&" + KeyURL(rsData) _
									+ """ TITLE=""" + GTM_EDIT_RECORD +"""><img src=images/edit.gif  border=0></A>  " 
									'+ """ TITLE=""" + GTM_EDIT_RECORD +""">" + AddFontTag(GTM_EDIT_CAPTION) + "</A> | " 
							ElseIf CheckAction(sTable, F_SECRETR) Then
								Response.Write "" _
									+ "<A CLASS=""gtmA"" HREF=""" + sPage + "?table=" + Server.URLEncode(sTable) _
									+ "&cmd=v&" + KeyURL(rsData) _
									+ """ TITLE=""" + GTM_VIEW_RECORD +""">" + AddFontTag(GTM_VIEW_CAPTION) + "</A> | " 
							End If
							
							If CheckAction(sTable, F_SECDEL) Then
								Response.Write "" _
									+ "<A CLASS=""gtmA"" HREF=""javascript:deleteRecord('" + Replace(Replace(KeyURL(rsData), "%27", "'"),"'","\'") _
									+ "', OldFile='" & sFileLookup & "', '" & sFieldLookup & "', FilePath='" & sFilePath & "');"" " _
									+ "TITLE=""" + GTM_DELETE_RECORD + """><img src=images/delete.gif border=0></A>"
									'+ "TITLE=""" + GTM_DELETE_RECORD + """>" + AddFontTag(GTM_DELETE_CAPTION) + "</A>"
							End If
									
							Response.Write "</TD>" + vbCrLf + "<TD>&nbsp;</TD>" + vbCrlf + "</TR>" + vbCrLf
									
							.MoveNext
							lRecIndex = lRecIndex + 1 
							bEOF = .EOF
				 		Wend
				 	End If
		 		End With
			End If
			Response.Write vbCrLF _
				&			"</TABLE>" & vbCrLf _
				&		"</TD>" & vbCrLf _
				&	"</TR>" & vbCrLf _
				& "</TABLE><BR>" + vbCrLf 
				
		Case Else		' Put list of tables
			Response.Write vbCrLf _
				& "<TABLE CLASS=""gtmTable"" BORDER=""0"" CELLSPACING=""0"" CELLPADDING=""0"">" & vbCrLf _
				&	"<tr valign=top CLASS=""gtmTr"">" & vbCrLf _
				&		"<TD CLASS=""gtmTableTitle"">" _
				&			AddFontTag(GTM_TABLE_CAPTION)  & vbCrLf _
				&		"</TD>" & vbCrLf _
				&	"</TR>" & vbCrLf _
				&	"<tr valign=top CLASS=""gtmTr"">" & vbCrLf _
				&		"<TD CLASS=""gtmSectionContentOut"" ONMOUSEOVER=""this.className='gtmSectionContentOver';""" _
				&			"ONMOUSEOUT=""this.className='gtmSectionContentOut';"">" & vbCrLf _
				&			"<TABLE CLASS=""gtmInnerTable"">" + vbCrLf 
			
			For Each sTableName In dicTables
				If dicTables.Count = 1 Then Response.Redirect sPage + "?cmd=r&table=" + Server.URLEncode(sTableName)
				
				If CheckAction(sTableName, F_SECRETR) Then
					Response.Write "<tr valign=top CLASS=""gtmTr""><TD CLASS=""gtmTd"">" + AddFontTag("<A CLASS=""gtmA"" HREF=""" + sPage + "?table=" + Server.URLEncode(sTableName) + _
						"&cmd=r"" TITLE=""" + GTM_EDIT_TABLE + """>" + dicTables(sTableName)(F_DESC) + "</A>") + "</TD></TR>" + vbCrLf
				End If
			Next
			
			Response.Write vbCrLf _
				&			"</TABLE>" & vbCrLf _
				&		"</TD>" & vbCrLf _
				&	"</TR>" & vbCrLf _
				& "</TABLE>" + vbCrLf 
	End Select
	Response.Write "</FORM>"
	If sCmd <> "" Then
		Response.Write vbCrLf _
			& "<DIV CLASS=""gtmMenu"">" & vbCrLf _
			&	"<P>"
		' Show / Hide links when only a table has been specified
		If dicTables.Count > 1 Then
			If CheckAction(sTable, F_SECPICK) Then			
				Response.Write vbCrLf _
					& AddFontTag("<A CLASS=""gtmA"" HREF=""" + sPage + """ TITLE=""" + GTM_PICK_TABLE + """>" + GTM_PICK_TABLE_CAPTION + "</A>")
			End If
		End If	
		If CheckAction(sTable, F_SECADD) Then
			Response.Write vbCrLf _
				& AddFontTag( " | <A CLASS=""gtmA"" HREF=""" + sPage + "?table=" + Server.URLEncode(sTable) + "&cmd=a"" TITLE=""" + GTM_ADD_RECORD + """>" & GTM_ADD_RECORD_CAPTION & "</A>" )
		End If
		If sCmd = "A" Or sCmd = "E" Or sCmd = "S" Then
			Response.Write AddFontTag(" | <A CLASS=""gtmA"" HREF=""" + sPage + "?cmd=r&table=" + Server.URLEncode(sTable) + """ TITLE=""" + _
				GTM_LIST_RECORDS + """>" + GTM_LIST_RECORDS_CAPTION + "</A>")
		End If
		
		If sCmd="R" Then
			If Not bBOF Then
				Response.Write AddFontTag(" | <A CLASS=""gtmA"" TITLE=""" + GTM_TABLE_PREV_CAPTION + """ HREF=""" + sPage + _
					"?page=" & (lPage-1) & "&cmd=r&table=" + Server.URLEncode(sTable) + """>" + GTM_TABLE_PREV + "</A>")
			End If
		
			If Not bEOF Then
				Response.Write AddFontTag(" | <A CLASS=""gtmA"" TITLE=""" + GTM_TABLE_NEXT_CAPTION + """ HREF=""" + sPage + _
					"?page=" & (lPage+1) & "&cmd=r&table=" + Server.URLEncode(sTable) + """>" + GTM_TABLE_NEXT + "</A>")
			End If
		End If
		Response.Write "</P></DIV>"
	End If
End Sub

Function CheckAction(sTableName, sActionName)
	CheckAction = InStr(dicTables(sTableName)(F_ACTIONSALLOWED), sActionName) > 0
End Function

Function IIf( condition, valTrue, valFalse )
	If ( condition ) Then
		IIf = valTrue
	Else
		IIf = valFalse
	End If
End Function

' Transforms the HTML string into a valid Javascript string.
'	sContent		Content to be transformed
Function HtmlToJSString(sContent)
	HtmlToJSString = Replace(sContent, vbCr, "")
	HtmlToJSString = Replace(HtmlToJSString, vbLf, "")
	HtmlToJSString = Replace(HtmlToJSString, """", "\""")
	HtmlToJSString = Replace(HtmlToJSString, "'", "\'")
End Function

%>